FADE NINJA

Often, one of the most repetitive tasks when programming a show in QLab is creating fades. Any audio cue you start, may require a fade out at some point, and often a fade in. This is a very short chapter that provides a  quick script method for creating fades in and out for audio cues.

In these examples, we will use simple stereo cues outputting to cue outputs 1+2 at 0dB. All level setting will be done with the master fader.

Before we look at the scripts,  we’ll have a quick look at the 2 main programming styles for fades

The starting point for both methods is the same.

  1. Drag a stereo audio file into the cue list to create an audio cue

If you are going to want to fade out the cue out at some point you might as well create that fade now and drag it, or cut and paste it into the required position, otherwise skip to the fade in section.

  1. Select the audio cue
  2. Create a fade cue underneath this cue by clicking the fade cue icon in the toolbar or keying cmd-5
  3. Set the target  of  the fade cue by dragging the audio cue on top of the fade cue
  4. Set the master level of the fade cue to out and click the ‘stop target when done checkbox’ (unless you are going to restore the level of a playing cue later.

To create a fade in (if required):

  1. Select the audio cue
  2. Create a fade cue underneath this cue by clicking the fade cue icon in the toolbar or keying cmd-5
  3. Set the target  of  the fade cue by dragging the audio cue on top of the fade cue
  4. Set the master level of the original audio cue to out
  5. Play the audio cue by pressing space.
  6. Check Live Preview is on and adjust the master level of the fade cue to the desired level
  7. Set the fade time in the action column of the fade cue.

There are now 2 main methods that can be used to make the fade in cue start immediately after the audio cue is triggered.

Method 1 Auto-Continue

  • Click in the rightmost column of the audio cue once, to create an auto-follow, indicated by a triple-headed arrow.

autoContinueMethod

Method 2 Fire All Group

If you are going to create fades using this method it is likely your default setting  for a group cue should be set to MODE  ‘Start all children simultaneously’ (in QLab 4:  settings/cue templates/group, in QLab 3: settings/group).

  1. Select the audio cue, and the fade in cue, by clicking the audio cue and shift-clicking the fade
  2. Click on the group cue  icon in the toolbar
  • The 2 cues will be placed inside  a group cue.
  • You can type a description of the cue in the Q column of the group cue.

groupmethod

Of these 2 methods, the group cue method (method 2) has many advantages.

  • It’s easier to see the structure of the cue list
  •  It’s easier to spot auto-follows that have been accidentally created, either by accidental clicking in the continue column, or if using the default keymap accidentally catching the hotkey for creating a continue. (‘C’-dangerously positioned directly above the space bar). As you rarely need to use them, if using the group cues method for continues, except in exceptional circumstances , it’s very easy to scan the entire cuelist to ensure that none exist where they shouldn’t
  • It creates a space in the group cue description for a title for the cue to be typed, without overwriting the descriptions that are automatically  created for the audio and fade cues, which again make the whole cue list more readable.

Here’s a screen capture of using method 2 to create an audio cue with a grouped fade in and a separate fade out, by non ninja means.

So, that took around a minute. A skilled operator might be able to do it in 30 seconds or so.

Now lets do the same thing Ninja Style

With one keystroke (ctrl-n) the fade in and fade out are created for the selected audio file in about 3 seconds.

How It Works:

There is a single script triggered by a hotkey (control-n)  which creates a fade out for the selected  audio cue and then, immediately below the audio cue, a fade in, which it groups with the audio cue and titles the group.

Here is the script (which you would probably want to put in a separate cue list):

Thanks to Rich Walsh for the difficult bits of script to move the cues into groups etc.

set inDuration to 5 –set fade in duration here
set outDuration to 10 –set fade in duration here
set minVolume to -60 — Set to match minimum volume set in settings/general
tell application id “com.figure53.QLab.4” to tell front workspace
try
set audioCue to last item of (selected as list)
set q number of audioCue to “”
if q type of audioCue is “Audio” then
make type “Fade”
set fadeOutCue to last item of (selected as list)
set the q number of fadeOutCue to “”
set cue target of fadeOutCue to audioCue
set duration of fadeOutCue to outDuration
fadeOutCue setLevel row 0 column 0 db minVolume
set stop target when done of fadeOutCue to true
set q name of fadeOutCue to “Fade out ” & q list name of audioCue & ” (” & outDuration & “s)”
set audioCueLevel to audioCue getLevel row 0 column 0
fadeOutCue setLevel row 0 column 0 db minVolume
moveSelectionUp
make type “Fade”
set fadeCue to last item of (selected as list)
set q number of fadeCue to “”
set cue target of fadeCue to audioCue
set duration of fadeCue to inDuration
fadeCue setLevel row 0 column 0 db audioCueLevel
audioCue setLevel row 0 column 0 db minVolume
set cuesToGroup to {audioCue, fadeCue}
make type “Group”
set groupCue to last item of (selected as list)
set mode of groupCue to fire_all
set q name of groupCue to “Fade in ” & q list name of audioCue & ” (” & inDuration & “s)”
repeat with eachCue in cuesToGroup
set eachCueID to uniqueID of eachCue
move cue id eachCueID of parent of eachCue to end of groupCue
end repeat
end if
end try
end tell

The script:

  • Has 2 variables where you can set the time in seconds for the in and out fades
  • Has a variable where you can set the slider volume setting that is used as the out volume. Usually this should be the same as what you have set for minimum volume in settings/general.
  • Checks to see if the selected cue is an audio cue
  • Makes a Fade cue for the out fade and sets its target to the audio cue
  • removes any cue number from that cue
  • Sets the  fade  duration
  • Stores the current level of the audio cues master slider to use in the fad in cue in a moment.
  • Sets the fade cue master to out  and checks the ‘stop target’ when done checkbox.
  • Titles the cue.
  • Re-selects the audio cue
  • Makes a Fade cue for the out fade, under the audio cue and sets its target to the audio cue
  • Removes any cue number from that cue
  • Sets the  fade  duration
  • Sets the level of the audio cue to out, and the level of the fade in cue to the original level of the audio cue
  • Titles the group cue to indicate what is going to happen when it is triggered
  • Selects the audio cue and the fade in cue
  • Brings them together  in a ‘start all children simultaneously’ group cue

You can download a workspace containing the script here

 

Chapter Author: Mic Pool

Chapter Graphic incorporating Ninja Png File
 from  http://www.freepngimg.com

 

Music used in the demos:
 Darkness is Coming Kevin MacLeod (incompetech.com)
Licensed under a Creative Commons Attribution 3.0 Unported License.
Creative Commons License

MenuGraphic